User:AnomieBOT/source/tasks/AFDMergeFromCleaner.pm
 | Approved 2009-01-03 Wikipedia:Bots/Requests for approval/AnomieBOT 20 |
package tasks::AFDMergeFromCleaner;
=pod
=begin metadata
Bot: AnomieBOT
Task: AFDMergeFromCleaner
BRFA: Wikipedia:Bots/Requests for approval/AnomieBOT 20
Status: Approved 2009-01-03
Created: 2008-12-29
Remove instances of {{tl|afd-merge from}} where the merge has been completed.
Report instances of {{tl|afd-merge from}} where the AFDed page is now a redirect
to a different target.
=end metadata
=cut
use utf8;
use strict;
use AnomieBOT::Task;
use vars qw/@ISA/;
@ISA=qw/AnomieBOT::Task/;
sub new {
my $class=shift;
my $self=$class->SUPER::new();
$self->{'nextrun'}=0;
bless $self, $class;
return $self;
}
=pod
=for info
Approved 2009-01-03<br />[[Wikipedia:Bots/Requests for approval/AnomieBOT 20]]
=cut
sub approved {
return 3;
}
sub run {
my ($self, $api)=@_;
my $res;
$api->task('AFDMergeFromCleaner', 0, 10, qw/d::Templates d::Redirects/);
if($self->{'nextrun'}==0 && exists($api->store->{'nextrun'})){
my $t=$api->store->{'nextrun'};
$self->{'nextrun'}=$t if $t=~/^\d+$/;
}
my $starttime=time();
my $t=$self->{'nextrun'}-$starttime;
return $t if $t>0;
my @templates=('Afd-merge from');
my $screwup=' Errors? [[User:'.$api->user.'/shutoff/AFDMergeFromCleaner]]';
my $report='User:'.$api->user.'/Afd-mergefrom report';
# Get a list of templates redirecting to our targets
my %templates=$api->redirects_to_resolved(map "Template:$_", @templates);
if(exists($templates{''})){
$api->warn("Failed to get redirects to target templates: ".$templates{''}{'error'}."\n");
return 60;
}
my %redirected=();
my %deleted=();
my $ret=21600;
my $linktmpl='User:'.$api->user.'/la';
MAINLOOP:
foreach my $template (@templates){
# Get the list of pages to check
my %q=(
list => 'embeddedin',
eititle => "Template:$template",
einamespace => 1,
eilimit => 'max',
);
do {
$res=$api->query(%q);
if($res->{'code'} ne 'success'){
$api->warn("Failed to retrieve transclusion list for $template: ".$res->{'error'}."\n");
$ret=60;
last MAINLOOP;
}
if(exists($res->{'query-continue'})){
$q{'eicontinue'}=$res->{'query-continue'}{'embeddedin'}{'eicontinue'};
} else {
delete $q{'eicontinue'};
}
# Process found pages
foreach (@{$res->{'query'}{'embeddedin'}}){
my $title=$_->{'title'};
my $subject=$title;
if($_->{'ns'}==1){
$subject=~s/^Talk://;
} else {
$subject=~s/^([^:]*) talk:/$1:/;
}
$res=$api->query(titles => $subject, redirects=>1);
if($res->{'code'} ne 'success'){
$api->warn("Failed to retrieve redirect target for $subject: ".$res->{'error'}."\n");
$ret=60;
last MAINLOOP;
}
my $rsubject=$subject;
foreach (@{$res->{'query'}{'redirects'}}){
$rsubject=$_->{'to'} if($_->{'from'} eq $rsubject);
}
$api->log("Checking for $template in $title");
# WTF?
if(exists($_->{'missing'})){
$api->warn("$title is missing? WTF?\n");
next;
}
# Ok, check the page
my $tok=$api->edittoken($title);
if($tok->{'code'} eq 'shutoff'){
$api->warn("Task disabled: ".$tok->{'content'}."\n");
return 300;
}
if($tok->{'code'} ne 'success'){
$api->warn("Failed to get edit token for $title: ".$tok->{'error'}."\n");
$ret=60;
last MAINLOOP;
}
next if exists($tok->{'missing'});
# Get page text
my $intxt=$tok->{'revisions'}[0]{'slots'}{'main'}{'*'};
# First, find the template and pull out the relevant parameter
my @from=();
$api->process_templates($intxt, sub {
return undef unless exists($templates{'Template:'.$_[0]});
my $f=undef;
foreach ($api->process_paramlist(@{$_[1]})){
($f=$_->{'value'})=~s/^\s+|\s+$//g if $_->{'name'} eq 1;
}
push @from, $f if defined($f);
return undef;
});
# Now, query the found pages
my %remove=();
while(@from){
my @f=splice(@from, 0, 500);
$res=$api->query(titles => join('|',@f), redirects=>1);
if($res->{'code'} ne 'success'){
$api->warn("Failed to retrieve mergefrom page list for $title: ".$res->{'error'}."\n");
$ret=60;
last MAINLOOP;
}
my %norm=map { $_->{'to'}, $_->{'from'} } @{$res->{'query'}{'normalized'}} if exists($res->{'query'}{'normalized'});
foreach (@{$res->{'query'}{'redirects'}}){
my ($f,$t)=($_->{'from'}, $_->{'to'});
if($t eq $subject || $t eq $rsubject){
$f=$norm{$f} if exists($norm{$f});
$remove{$f}=1;
} elsif($subject ne $rsubject){
$redirected{"$f>$rsubject>$t"}="| {{$linktmpl|$f}} || {{$linktmpl|$subject}}<br />→ {{$linktmpl|$rsubject}} || {{$linktmpl|$t}} || ";
} else {
$redirected{"$f>$subject>$t"}="| {{$linktmpl|$f}} || {{$linktmpl|$subject}} || {{$linktmpl|$t}} || ";
}
}
foreach (values %{$res->{'query'}{'pages'}}){
next unless exists($_->{'missing'});
# Missing pages should have the template removed, and
# be logged.
my $f=$_->{'title'};
$f=$norm{$f} if exists($norm{$f});
$remove{$f}=2;
$deleted{"$f>$subject"}="| {{$linktmpl|$f}} || {{$linktmpl|$subject}} || ";
}
}
# Remove the removable templates
my $outtxt=$api->process_templates($intxt, sub {
my $name=shift;
my @params=@{shift()};
shift; # $wikitext
shift; # $data
my $oname=shift;
return undef unless exists($templates{'Template:'.$name});
my $f=undef;
foreach ($api->process_paramlist(@params)){
($f=$_->{'value'})=~s/^\s+|\s+$//g if $_->{'name'} eq 1;
}
return undef unless exists($remove{$f});
return '' if $remove{$f}==2;
$oname=~s/_/ /g;
$oname=~s/^(\s*)\S(?:.*\S)?(\s*)$/${1}afd-merged-from$2/is;
return "{{$oname|".join("|",@params)."}}";
});
# Need to edit?
if($outtxt ne $intxt){
my $summary="Removing obsolete {{$template}}";
$api->log("$summary in $title");
my $r=$api->edit($tok, $outtxt, $summary.$screwup, 1, 1);
if($r->{'code'} ne 'success'){
$api->warn("Write failed on $title: ".$r->{'error'}."\n");
next;
}
}
}
} while(exists($q{'eicontinue'}));
}
if($ret==21600){ # No error above
my $tok=$api->edittoken($report);
if($tok->{'code'} eq 'shutoff'){
$api->warn("Task disabled: ".$tok->{'content'}."\n");
return 300;
}
if($tok->{'code'} ne 'success'){
$api->warn("Failed to get edit token for $report: ".$tok->{'error'}."\n");
$ret=60;
last;
}
my $intxt=$tok->{'revisions'}[0]{'slots'}{'main'}{'*'} // '';
foreach my $s (split(/(?=(?:^|\n)==)/, $intxt)){
if($s=~/^\n?==\s*Redirected\s*==/){
$s=~s/\|}.*$//s;
foreach (split /\n\|-\n/, $s){
s/[\r\n]\s*$//;
next unless /^\Q| {{$linktmpl|\E([^]]+)\Q}} || {{$linktmpl|\E([^]]+)\Q}} || {{$linktmpl|\E([^]]+)\Q}} ||/;
next unless exists($redirected{"$1>$2>$3"});
$redirected{"$1>$2>$3"}=$_;
}
} elsif($s=~/^\n?==\s*Deleted\s*==/){
$s=~s/\|}.*$//s;
foreach (split /\n\|-\n/, $s){
s/[\r\n]\s*$//;
next unless /^\Q| {{$linktmpl|\E([^]]+)\Q}} || {{$linktmpl|\E([^]]+)\Q}} ||/;
$deleted{"$1>$2"}=$_;
}
}
}
my $outtxt="== Redirected ==\n";
$outtxt.="The following table lists pages referred to by {{tl|afd-merge from}} are redirects to some page other than that with the {{tl|afd-merge from}}. Please correct the {{tl|afd-merge from}}, either by removing it (if the page was correctly merged elsewhere), undoing the incorrect redirection, or pointing it to the correct page. This table will be updated automatically.\n\n";
$outtxt.="{| class=\"wikitable sortable\"\n";
$outtxt.="! Page !! AFD merge to !! Redirect to !! Note\n";
$outtxt.="|-\n";
$outtxt.=join("\n|-\n", sort values %redirected);
$outtxt.="\n|}\n\n";
$outtxt.="== Deleted ==\n";
$outtxt.="The following table lists deleted pages that were referred to by {{tl|afd-merge from}}; the offending {{tl|afd-merge from}} has already been removed. Please double-check whether the deletion was correct. If so, just remove the row from the table; if not, undelete the page and restore the {{tl|afd-merge from}}. This table will '''not''' be updated automatically.\n\n";
$outtxt.="{| class=\"wikitable sortable\"\n";
$outtxt.="! Page !! AFD merge to !! Note\n";
$outtxt.="|-\n";
$outtxt.=join("\n|-\n", sort values %deleted);
$outtxt.="\n|}\n\n";
if($outtxt ne $intxt){
my $summary="Updating list of non-matching merges";
$api->log("$summary in $report");
my $r=$api->edit($tok, $outtxt, $summary.$screwup, 1, 1);
if($r->{'code'} ne 'success'){
$api->warn("Write failed on $report: ".$r->{'error'}."\n");
$ret=60;
}
}
}
$starttime+=$ret;
$self->{'nextrun'}=$starttime;
$api->store->{'nextrun'}=$starttime;
return $ret;
}
1;